Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

UDSDemo.CSSkaarjTrooper


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
00636
00637
00638
00639
00640
00641
00642
00643
00644
00645
00646
00647
00648
00649
00650
00651
00652
00653
00654
00655
00656
00657
00658
00659
00660
00661
00662
00663
00664
00665
00666
00667
00668
00669
00670
00671
00672
00673
00674
00675
00676
00677
00678
00679
00680
00681
00682
00683
00684
00685
00686
00687
00688
00689
00690
00691
00692
00693
00694
00695
00696
00697
00698
00699
00700
00701
00702
00703
00704
00705
00706
00707
00708
00709
00710
00711
00712
00713
00714
00715
00716
00717
00718
00719
00720
00721
00722
00723
00724
00725
00726
00727
00728
00729
00730
00731
00732
00733
00734
00735
00736
00737
00738
00739
00740
00741
00742
00743
00744
00745
00746
00747
00748
00749
00750
00751
00752
00753
00754
00755
00756
00757
00758
00759
00760
00761
00762
00763
00764
00765
00766
00767
00768
00769
00770
00771
00772
00773
00774
00775
00776
00777
00778
00779
00780
00781
00782
00783
00784
00785
00786
00787
00788
00789
00790
00791
00792
00793
00794
00795
00796
00797
00798
00799
00800
00801
00802
00803
00804
00805
00806
00807
00808
00809
00810
00811
00812
00813
00814
00815
00816
00817
00818
00819
00820
00821
00822
00823
00824
00825
//=============================================================================
// The Unreal Director's Suite                  Release version: Jan 7th, 1999
//=============================================================================
//
// [ CSSkaarjTrooper ]
//
// This actor has been included to show as an example of how to get greater 
// control over the actors in your Cut Sequence.
//
//=============================================================================

class CSSkaarjTrooper expands CSSkaarj;
 	
#exec MESH IMPORT MESH=sktrooper ANIVFILE=MODELS\zaarj_a.3D DATAFILE=MODELS\zaarj_d.3D 
#exec MESH ORIGIN MESH=sktrooper X=0 Y=-150 Z=-20 YAW=64 ROLL=-64
 
#exec MESH SEQUENCE MESH=sktrooper SEQ=All			STARTFRAME=0  NUMFRAMES=583
#exec MESH SEQUENCE MESH=sktrooper SEQ=Claw         STARTFRAME=0   NUMFRAMES=13  RATE=15    Group=Attack
#exec MESH SEQUENCE MESH=sktrooper SEQ=GutHit       STARTFRAME=13  NUMFRAMES=1				Group=TakeHit
#exec MESH SEQUENCE MESH=sktrooper SEQ=Breath       STARTFRAME=14  NUMFRAMES=12  RATE=6		Group=Waiting
#exec MESH SEQUENCE MESH=sktrooper SEQ=Breath2      STARTFRAME=26  NUMFRAMES=8   RATE=6		Group=Waiting  
#exec MESH SEQUENCE MESH=sktrooper SEQ=MButton1     STARTFRAME=34  NUMFRAMES=33  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=MButton2     STARTFRAME=44  NUMFRAMES=46  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=MButton3     STARTFRAME=54  NUMFRAMES=23  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=MButton4     STARTFRAME=67  NUMFRAMES=23  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Button1      STARTFRAME=34  NUMFRAMES=10  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Taunt1       STARTFRAME=34  NUMFRAMES=10  RATE=15	Group=Gesture
#exec MESH SEQUENCE MESH=sktrooper SEQ=Button2      STARTFRAME=44  NUMFRAMES=10  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Button3      STARTFRAME=54  NUMFRAMES=13  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Button4      STARTFRAME=67  NUMFRAMES=10  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Button5      STARTFRAME=77  NUMFRAMES=13  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Death        STARTFRAME=90  NUMFRAMES=21  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Death2       STARTFRAME=111 NUMFRAMES=13  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Death3       STARTFRAME=124 NUMFRAMES=21  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Death4       STARTFRAME=145 NUMFRAMES=11  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Duck         STARTFRAME=156 NUMFRAMES=1				Group=Ducking
#exec MESH SEQUENCE MESH=sktrooper SEQ=Fighter      STARTFRAME=157 NUMFRAMES=15  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Firing       STARTFRAME=172 NUMFRAMES=5   RATE=15	Group=Waiting
#exec MESH SEQUENCE MESH=sktrooper SEQ=Getup        STARTFRAME=177 NUMFRAMES=11  RATE=15    
#exec MESH SEQUENCE MESH=sktrooper SEQ=guncheck     STARTFRAME=188 NUMFRAMES=7   RATE=6
#exec MESH SEQUENCE MESH=sktrooper SEQ=gunfix       STARTFRAME=195 NUMFRAMES=8   RATE=6
#exec MESH SEQUENCE MESH=sktrooper SEQ=HeadHit      STARTFRAME=203 NUMFRAMES=1				Group=TakeHit
#exec MESH SEQUENCE MESH=sktrooper SEQ=Headup       STARTFRAME=204 NUMFRAMES=10  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Jog2Fight    STARTFRAME=214 NUMFRAMES=10  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=FullJump     STARTFRAME=224 NUMFRAMES=15  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Jump         STARTFRAME=224 NUMFRAMES=5   RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=InAir        STARTFRAME=230 NUMFRAMES=1				Group=Jumping
#exec MESH SEQUENCE MESH=sktrooper SEQ=Landed       STARTFRAME=234 NUMFRAMES=1				Group=Landing
#exec MESH SEQUENCE MESH=sktrooper SEQ=Jump2        STARTFRAME=239 NUMFRAMES=1				Group=Jumping
#exec MESH SEQUENCE MESH=sktrooper SEQ=Land         STARTFRAME=240 NUMFRAMES=1				Group=Landing
#exec MESH SEQUENCE MESH=sktrooper SEQ=LeftDodge    STARTFRAME=241 NUMFRAMES=13  RATE=15    Group=Dodge
#exec MESH SEQUENCE MESH=sktrooper SEQ=LeftHit      STARTFRAME=254 NUMFRAMES=1				Group=TakeHit
#exec MESH SEQUENCE MESH=sktrooper SEQ=StrafeLeftFr STARTFRAME=255 NUMFRAMES=14  RATE=15	Group=MovingAttack
#exec MESH SEQUENCE MESH=sktrooper SEQ=Looking      STARTFRAME=269 NUMFRAMES=23  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=StrafeLeft   STARTFRAME=292 NUMFRAMES=14  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Lunge        STARTFRAME=306 NUMFRAMES=13  RATE=15    Group=Dodge
#exec MESH SEQUENCE MESH=sktrooper SEQ=RightDodge   STARTFRAME=319 NUMFRAMES=13  RATE=15    Group=Dodge
#exec MESH SEQUENCE MESH=sktrooper SEQ=StrafeRightFr STARTFRAME=332 NUMFRAMES=14 RATE=15	Group=MovingAttack
#exec MESH SEQUENCE MESH=sktrooper SEQ=RightHit     STARTFRAME=346 NUMFRAMES=1				Group=TakeHit
#exec MESH SEQUENCE MESH=sktrooper SEQ=StrafeRight  STARTFRAME=347 NUMFRAMES=14  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Jog          STARTFRAME=361 NUMFRAMES=10  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=JogFire      STARTFRAME=371 NUMFRAMES=10  RATE=15	Group=MovingAttack
#exec MESH SEQUENCE MESH=sktrooper SEQ=ShldDown     STARTFRAME=381 NUMFRAMES=10 
#exec MESH SEQUENCE MESH=sktrooper SEQ=ShldFire     STARTFRAME=391 NUMFRAMES=1				Group=Shielded
#exec MESH SEQUENCE MESH=sktrooper SEQ=ShldLand     STARTFRAME=392 NUMFRAMES=1				Group=Shielded
#exec MESH SEQUENCE MESH=sktrooper SEQ=ShldTest     STARTFRAME=393 NUMFRAMES=20  RATE=15 
#exec MESH SEQUENCE MESH=sktrooper SEQ=ShldUp       STARTFRAME=413 NUMFRAMES=16 
#exec MESH SEQUENCE MESH=sktrooper SEQ=HoldShield   STARTFRAME=428 NUMFRAMES=1				Group=Shielded
#exec MESH SEQUENCE MESH=sktrooper SEQ=Spin         STARTFRAME=429 NUMFRAMES=20             Group=Attack
#exec MESH SEQUENCE MESH=sktrooper SEQ=Swim         STARTFRAME=449 NUMFRAMES=15  RATE=15	Group=Waiting
#exec MESH SEQUENCE MESH=sktrooper SEQ=Walk         STARTFRAME=464 NUMFRAMES=15  RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=WalkFire     STARTFRAME=479 NUMFRAMES=15  RATE=15	Group=MovingAttack 
#exec MESH SEQUENCE MESH=sktrooper SEQ=Turn         STARTFRAME=464 NUMFRAMES=2   RATE=15
#exec MESH SEQUENCE MESH=sktrooper SEQ=Death5       STARTFRAME=494 NUMFRAMES=31  RATE=15	 
#exec MESH SEQUENCE MESH=sktrooper SEQ=DuckWalk     STARTFRAME=525 NUMFRAMES=15  RATE=15	 
#exec MESH SEQUENCE MESH=sktrooper SEQ=Pickup       STARTFRAME=540 NUMFRAMES=15  RATE=15	 
#exec MESH SEQUENCE MESH=sktrooper SEQ=Shield       STARTFRAME=555 NUMFRAMES=28  RATE=15	 

#exec OBJ LOAD FILE=textures\stshield.utx PACKAGE=UNREALI.STEffect
#exec TEXTURE IMPORT NAME=sktrooper1 FILE=MODELS\zaarj.PCX GROUP=Skins 
#exec MESHMAP SCALE MESHMAP=sktrooper X=0.086 Y=0.086 Z=0.172
#exec MESHMAP SETTEXTURE MESHMAP=sktrooper NUM=0 TEXTURE=sktrooper1
#exec MESHMAP SETTEXTURE MESHMAP=sktrooper NUM=1 TEXTURE=UNREALI.STEffect.stshield

#exec MESH NOTIFY MESH=sktrooper SEQ=WalkFire TIME=0.5 FUNCTION=SpawnTwoShots
#exec MESH NOTIFY MESH=sktrooper SEQ=JogFire TIME=0.5 FUNCTION=SpawnTwoShots
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeLeftFr TIME=0.5 FUNCTION=SpawnTwoShots
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeRightFr TIME=0.5 FUNCTION=SpawnTwoShots
#exec MESH NOTIFY MESH=sktrooper SEQ=Spin TIME=0.48 FUNCTION=SpinDamageTarget
#exec MESH NOTIFY MESH=sktrooper SEQ=Spin TIME=0.67 FUNCTION=SpinDamageTarget
#exec MESH NOTIFY MESH=sktrooper SEQ=Claw TIME=0.24 FUNCTION=ClawDamageTarget
#exec MESH NOTIFY MESH=sktrooper SEQ=Claw TIME=0.76 FUNCTION=ClawDamageTarget
#exec MESH NOTIFY MESH=sktrooper SEQ=Death  TIME=0.41 FUNCTION=LandThump
#exec MESH NOTIFY MESH=sktrooper SEQ=Death2 TIME=0.61 FUNCTION=LandThump
#exec MESH NOTIFY MESH=sktrooper SEQ=Death3 TIME=0.73 FUNCTION=LandThump
#exec MESH NOTIFY MESH=sktrooper SEQ=Death4 TIME=0.62 FUNCTION=LandThump
#exec MESH NOTIFY MESH=sktrooper SEQ=Death5 TIME=0.8  FUNCTION=LandThump
#exec MESH NOTIFY MESH=sktrooper SEQ=Walk TIME=0.3 FUNCTION=WalkStep
#exec MESH NOTIFY MESH=sktrooper SEQ=Walk TIME=0.8 FUNCTION=WalkStep
#exec MESH NOTIFY MESH=sktrooper SEQ=WalkFire TIME=0.3 FUNCTION=WalkStep
#exec MESH NOTIFY MESH=sktrooper SEQ=WalkFire TIME=0.8 FUNCTION=WalkStep
#exec MESH NOTIFY MESH=sktrooper SEQ=Jog TIME=0.25 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=Jog TIME=0.75 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=JogFire TIME=0.25 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=JogFire TIME=0.75 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeLeft TIME=0.25 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeLeft TIME=0.75 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeLeftFr TIME=0.25 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeLeftFr TIME=0.75 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeRight TIME=0.25 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeRight TIME=0.75 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeRightFr TIME=0.25 FUNCTION=RunStep
#exec MESH NOTIFY MESH=sktrooper SEQ=StrafeRightFr TIME=0.75 FUNCTION=RunStep

//-----------------------------------------------------------------------------
// SkaarjTrooper variables.

var() class<weapon> WeaponType;
var	  Weapon myWeapon;
var   float  duckTime;

//=========================================================================================


function PreBeginPlay()
{
	Super.PreBeginPlay();

	if ( TimeBetweenAttacks == Default.TimeBetweenAttacks )
		TimeBetweenAttacks = TimeBetweenAttacks + (3 - Skill) * 0.3;
	bHasRangedAttack = false;
	bMovingRangedAttack = false;
}

function ChangedWeapon()
{
	Super.ChangedWeapon();
	bIsPlayer = false;
	bMovingRangedAttack = true;
	bHasRangedAttack = true;
	Weapon.AimError += 200;
	Weapon.FireOffset = Weapon.FireOffset * 1.5 * DrawScale;
	Weapon.PlayerViewOffset = Weapon.PlayerViewOffset * 1.5 * DrawScale; 
	//Weapon.SetHand(0);
}

function TossWeapon()
{
	if ( Weapon == None )
		return;
	Weapon.FireOffset = Weapon.Default.FireOffset;
	Weapon.PlayerViewOffset = Weapon.Default.PlayerViewOffset; 
	Super.TossWeapon();
}

function Died(pawn Killer, name damageType, vector HitLocation)
{
	bIsPlayer = false;
	Super.Died(Killer, damageType, HitLocation);
}

function PlayTakeHit(float tweentime, vector HitLoc, int damage)
{
	if ( GetAnimGroup(AnimSequence) == 'Shielded' )
		TweenAnim('ShldLand', 0.5);
	else
		Super.PlayTakeHit(tweentime, HitLoc, damage);
}

auto state Startup
{
	function BeginState()
	{
		Super.BeginState();
		bIsPlayer = true; // temporarily, till have weapon
		if ( WeaponType != None )
		{
			bIsPlayer = true;
			myWeapon = Spawn(WeaponType);
			if ( myWeapon != None )
				myWeapon.ReSpawnTime = 0.0;
		}
	}

	function SetHome()
	{
		Super.SetHome();
		if ( myWeapon != None )
			myWeapon.Touch(self);
	}
}

function Shield()
{
	bFire = 0;
	bAltFire = 0;
	PlayAnim('ShldUp', 2.0, 0.1);
	GotoState('RangedAttack', 'Shieldup');
}

function WarnTarget(Pawn shooter, float projSpeed, vector FireDir)
{
	local float enemyDist;
	local eAttitude att;
	local vector X,Y,Z, enemyDir;

	att = AttitudeTo(shooter);
	if ( (att == ATTITUDE_Ignore) || (att == ATTITUDE_Threaten) )
	{
		if ( intelligence >= BRAINS_Mammal )
			damageAttitudeTo(shooter);
		if (att == ATTITUDE_Ignore)
			return;	
	}
	
	// AI controlled creatures may duck if not falling
	if ( (Enemy == None) || (Physics == PHYS_Falling) || (FRand() > 0.4 + 0.2 * skill) )
		return;

	// and projectile time is long enough
	enemyDist = VSize(shooter.Location - Location);
	duckTime = enemyDist/projSpeed;
	if (duckTime < 0.1 + 0.15 * FRand()) //FIXME - pick right value
		return;
					
	// only if tight FOV
	GetAxes(Rotation,X,Y,Z);
	enemyDir = (shooter.Location - Location)/enemyDist;
	if ((enemyDir Dot X) < 0.8)
		return;

	if ( (FireDir Dot Y) > 0 )
	{
		Y *= -1;
		TryToDuck(Y, true);
	}
	else
		TryToDuck(Y, false);
}

function TryToDuck(vector duckDir, bool bReversed)
{
	local vector HitLocation, HitNormal, Extent;
	local bool duckLeft;
	local actor HitActor;

	if ( (FRand() < 0.4) || (VSize(Velocity) < 50) )
	{
		Shield();
		return;
	}
				
	duckDir.Z = 0;
	duckLeft = !bReversed;

	Extent.X = CollisionRadius;
	Extent.Y = CollisionRadius;
	Extent.Z = CollisionHeight;
	HitActor = Trace(HitLocation, HitNormal, Location + 200 * duckDir, Location, false, Extent);
	if (HitActor != None)
	{
		duckLeft = !duckLeft;
		duckDir *= -1;
		HitActor = Trace(HitLocation, HitNormal, Location + 200 * duckDir, Location, false, Extent);
	}
	if (HitActor != None)
	{
		Shield();
		return;
	}

	HitActor = Trace(HitLocation, HitNormal, Location + 200 * duckDir - MaxStepHeight * vect(0,0,1), Location + 200 * duckDir, false, Extent);
	if (HitActor == None)
	{
		Shield();
		return;
	}

	SetFall();
	if ( duckLeft )
		PlayAnim('LeftDodge', 1.35);
	else
		PlayAnim('RightDodge', 1.35);
	Velocity = duckDir * GroundSpeed;
	Velocity.Z = 200;
	SetPhysics(PHYS_Falling);
	GotoState('FallingState','Ducking');
}	

function bool CanFireAtEnemy()
{
	local vector HitLocation, HitNormal,X,Y,Z, projStart, EnemyDir, EnemyUp;
	local actor HitActor;
	local float EnemyDist;
		
	EnemyDir = Enemy.Location - Location;
	EnemyDist = VSize(EnemyDir);
	EnemyUp = Enemy.CollisionHeight * vect(0,0,0.8);
	if ( EnemyDist > 300 )
	{
		EnemyDir = 300 * EnemyDir/EnemyDist;
		EnemyUp = 300 * EnemyUp/EnemyDist;
	}
	
	if ( Weapon == None )
		return false;
	
	GetAxes(Rotation,X,Y,Z);
	projStart = Location + Weapon.CalcDrawOffset() + Weapon.FireOffset.X * X + 1.2 * Weapon.FireOffset.Y * Y + Weapon.FireOffset.Z * Z;
	if ( Weapon.IsA('ASMD') || Weapon.IsA('Minigun') || Weapon.IsA('Rifle') ) //instant hit
		HitActor = Trace(HitLocation, HitNormal, Enemy.Location + EnemyUp, projStart, true);
	else
		HitActor = Trace(HitLocation, HitNormal, projStart + EnemyDir + EnemyUp, projStart, true);

	if ( HitActor == Enemy )
		return true;
	if ( (HitActor != None) && (VSize(HitLocation - Location) < 200) )
		return false;
	if ( (Pawn(HitActor) != None) && (AttitudeTo(Pawn(HitActor)) > ATTITUDE_Ignore) )
		return false;

	return true;
}

function PlayCock()
{
	if ( Weapon != None )
	{
		if ( Weapon.CockingSound != None )
			PlaySound(Weapon.CockingSound, SLOT_Interact,,,700);
		else if ( Weapon.SelectSound != None )
			PlaySound(Weapon.CockingSound, SLOT_Interact,,,700);
	}
}

//Skaarj animations
function PlayPatrolStop()
{
	if (Region.Zone.bWaterZone)
	{
		PlaySwimming();
		return;
	}
	if ( bButtonPusher )
	{
		PushButtons();
		return;
	}

	SetAlertness(0.2);	
	LoopAnim('Breath', 0.3 + 0.6 * FRand());
}

function PlayChallenge()
{
	if (Region.Zone.bWaterZone)
	{
		PlaySwimming();
		return;
	}
	if ( TryToCrouch() )
	{
		TweenAnim('Duck', 0.12);
		return;
	}	
	PlayThreateningSound();
	PlayAnim('Fighter', 0.8 + 0.5 * FRand(), 0.1);
}

function PlayRunning()
{
	local float strafeMag;
	local vector Focus2D, Loc2D, Dest2D;
	local vector lookDir, moveDir, Y;

	bFire = 0;
	bAltFire = 0;
	DesiredSpeed = MaxDesiredSpeed;
	if (Region.Zone.bWaterZone)
	{
		PlaySwimming();
		return;
	}

	if (Focus == Destination)
	{
		LoopAnim('Jog', -0.9/GroundSpeed,, 0.5);
		return;
	}	
	Focus2D = Focus;
	Focus2D.Z = 0;
	Loc2D = Location;
	Loc2D.Z = 0;
	Dest2D = Destination;
	Dest2D.Z = 0;
	lookDir = Normal(Focus2D - Loc2D);
	moveDir = Normal(Dest2D - Loc2D);
	strafeMag = lookDir dot moveDir;
	if (strafeMag > 0.8)
		LoopAnim('Jog', -1.0/GroundSpeed,, 0.5);
	else if (strafeMag < -0.8)
		LoopAnim('Jog', -1.0/GroundSpeed,, 0.5);
	else
	{
		Y = (lookDir Cross vect(0,0,1));
		if ((Y Dot (Dest2D - Loc2D)) > 0)
		{
			if ( (AnimSequence == 'StrafeRight') || (AnimSequence == 'StrafeRightFr') ) 
				LoopAnim('StrafeRight', -2.5/GroundSpeed,, 1.0);
			else 
				LoopAnim('StrafeRight', -2.5/GroundSpeed,0.1, 1.0);
		}
		else
		{
			if ( (AnimSequence == 'StrafeLeft') || (AnimSequence == 'StrafeLeftFr') ) 
				LoopAnim('StrafeLeft', -2.5/GroundSpeed,, 1.0);
			else
				LoopAnim('StrafeLeft', -2.5/GroundSpeed,0.1, 1.0);
		}
	}
}

function PlayMovingAttack()
{
	local float strafeMag;
	local vector Focus2D, Loc2D, Dest2D;
	local vector lookDir, moveDir, Y;
	local int bUseAltMode;

	if (Weapon != None)
	{
		if ( Weapon.AmmoType != None )
			Weapon.AmmoType.AmmoAmount = Weapon.AmmoType.Default.AmmoAmount;
		Weapon.RateSelf(bUseAltMode);
		ViewRotation = Rotation;
		if ( bUseAltMode == 0 ) 
		{
			bFire = 1;
			bAltFire = 0;
			Weapon.Fire(1.0);
		}
		else
		{
			bFire = 0;
			bAltFire = 1;
			Weapon.AltFire(1.0);
		}
	}
	else
	{
		PlayRunning();
		return;
	}

	if (Region.Zone.bWaterZone)
	{
		PlaySwimming();
		return;
	}

	DesiredSpeed = MaxDesiredSpeed;

	if (Focus == Destination)
	{
		LoopAnim('JogFire', -0.9/GroundSpeed,, 0.4);
		return;
	}	
	Focus2D = Focus;
	Focus2D.Z = 0;
	Loc2D = Location;
	Loc2D.Z = 0;
	Dest2D = Destination;
	Dest2D.Z = 0;
	lookDir = Normal(Focus2D - Loc2D);
	moveDir = Normal(Dest2D - Loc2D);
	strafeMag = lookDir dot moveDir;
	if (strafeMag > 0.8)
		LoopAnim('JogFire', -1.0/GroundSpeed,, 0.4);
	else if (strafeMag < -0.8)
		LoopAnim('JogFire', -1.0/GroundSpeed,, 0.4);
	else
	{
		MoveTimer += 0.2;
		DesiredSpeed = 0.6;
		Y = (lookDir Cross vect(0,0,1));
		if ((Y Dot (Dest2D - Loc2D)) > 0) 
		{
			if ( (AnimSequence == 'StrafeRight') || (AnimSequence == 'StrafeRightFr') ) 
				LoopAnim('StrafeRightFr', -2.5/GroundSpeed,, 1.0); 
			else
				LoopAnim('StrafeRightFr', -2.5/GroundSpeed,0.1, 1.0); 
		}
		else
		{
			if ( (AnimSequence == 'StrafeLeft') || (AnimSequence == 'StrafeLeftFr') ) 
				LoopAnim('StrafeLeftFr', -2.5/GroundSpeed,, 1.0);
			else
				LoopAnim('StrafeLeftFr', -2.5/GroundSpeed,0.1, 1.0);
		}
	}
}

function PlayThreatening()
{
	local float decision, animspeed;

	if (Region.Zone.bWaterZone)
	{
		PlaySwimming();
		return;
	}

	decision = FRand();
	animspeed = 0.4 + 0.6 * FRand(); 
	
	if ( decision < 0.7 )
		PlayAnim('Breath2', animspeed, 0.3);
	else
	{
		PlayThreateningSound();
		PlayAnim('Fighter', animspeed, 0.3);
	}
}

function PlayRangedAttack()
{
	PlayFiring();
}

function PlayFiring()
{
	TweenAnim('Firing', 0.2);
	if ( (Weapon != None) && (Weapon.AmmoType != None) )
		Weapon.AmmoType.AmmoAmount = Weapon.AmmoType.Default.AmmoAmount;
}

function PlayVictoryDance()
{
	PlayAnim('Shield', 0.6, 0.1);
}

function PlayLanded(float impactVel)
{
	if ( GetAnimGroup(AnimSequence) == 'Shielded' )
		TweenAnim('ShldLand', 0.1);
	else if (impactVel > 1.7 * JumpZ)
		PlayAnim('Landed',1.0,0.1);
	else
		TweenAnim('Land', 0.1);
}

state TakeHit 
{
ignores seeplayer, hearnoise, bump, hitwall;

	function BeginState()
	{
		bFire = 0;
		bAltFire = 0;
		Super.BeginState();
	}
}

state Retreating
{
ignores SeePlayer, EnemyNotVisible, HearNoise;

	function EndState()
	{
		bFire = 0;
		bAltFire = 0;
		Super.EndState();
	}
}

state Charging
{
ignores SeePlayer, HearNoise;

	function EndState()
	{
		bFire = 0;
		bAltFire = 0;
		Super.EndState();
	}
}

state TacticalMove
{
ignores SeePlayer, HearNoise;

	function EndState()
	{
		bFire = 0;
		bAltFire = 0;
		Super.EndState();
	}
}

state Hunting
{
ignores EnemyNotVisible; 

	function EndState()
	{
		bFire = 0;
		bAltFire = 0;
		if ( !Region.Zone.bWaterZone )
			bCanSwim = false;
		Super.EndState();
	}
}

state MeleeAttack
{
ignores SeePlayer, HearNoise, Bump;

ShieldDown:
	DesiredRotation = Rotator(Enemy.Location - Location);
	FinishAnim();
	Goto('Begin');
}


state RangedAttack
{
ignores SeePlayer, HearNoise;
	
	function TakeDamage( int Damage, Pawn instigatedBy, Vector hitlocation, 
						Vector momentum, name damageType)
	{
		if ( (GetAnimGroup(AnimSequence) == 'Shielded') && (AnimSequence != 'ShldFire')
			&& ((Vector(Rotation) Dot Momentum) < -0.6) )
			Damage *= 0.2; 

		Super.TakeDamage(Damage, instigatedBy, hitlocation, momentum, damageType);
	}

	function Bump (Actor Other)
	{
		if ( (GetAnimGroup(AnimSequence) == 'Shielded') && (Other == Enemy) )
		{
			PlayAnim('ShldDown');
			GotoState('MeleeAttack', 'ShieldDown');
			return;
		}
		if ( AttackSuccess || (AnimSequence != 'Lunge') )
		{
			Disable('Bump');
			return;
		}
		else		
			LungeDamageTarget();

		if (!AttackSuccess && Pawn(Other) != None) //always add momentum
			Pawn(Other).AddVelocity((60000.0 * (Normal(Other.Location - Location)))/Other.Mass);
	}
	
	function PlayRangedAttack()
	{
		local float dist;

		if ( GetAnimGroup(AnimSequence) == 'Shielded' )
		{
			TweenAnim('ShldFire', 0.05);
			FireWeapon();
			return;
		}

		dist = VSize(Target.Location - Location + vect(0,0,1) * (CollisionHeight - Target.CollisionHeight));
		if ( (FRand() < 0.2) && (dist < 150 + CollisionRadius + Target.CollisionRadius) && (Region.Zone.bWaterZone || !Target.Region.Zone.bWaterZone) )
		{
			PlaySound(Lunge, SLOT_Interact);
	 		Velocity = 500 * (Target.Location - Location)/dist; //instant acceleration in that direction 
	 		Velocity.Z += 1.5 * dist;
	 		if (Physics != PHYS_Swimming)
	 			SetPhysics(PHYS_Falling);
	 		Enable('Bump');
	 		PlayAnim('Lunge');
	 	}
		else
		{
			Disable('Bump');
			FireWeapon();
		}
	}

	function TryToDuck(vector duckDir, bool bReversed)
	{
		if ( FRand() < 0.5 )
			return;
			
		bFire = 0;
		bAltFire = 0;
		if ( AnimSequence == 'ShldFire' )
		{
			TweenAnim('HoldShield', 0.15);
			GotoState('RangedAttack', 'Shieldup');
			return;
		}
		if ( GetAnimGroup(AnimSequence) == 'Shielded' )
		{
			if (FRand() < 0.75)
				GotoState('RangedAttack', 'ShieldUp');
			return;
		}

		Shield();
	}

	function KeepAttacking()
	{
		if ( bFiringPaused )
			return;
		if ( (FRand() > ReFireRate) || (Enemy == None) || (Enemy.Health <= 0) || !CanFireAtEnemy() ) 
		{
			if ( GetAnimGroup(AnimSequence) == 'Shielded' )
			{
				PlayAnim('ShldDown');
				GotoState('RangedAttack', 'ShieldDown');
			}
			else
				GotoState('Attacking');
		}
	}


	function AnimEnd()
	{
		if ( (AnimSequence == 'Lunge') || (FRand() < 0.5) || ((bFire == 0) && (bAltFire == 0)) )
			GotoState('RangedAttack', 'DoneFiring');
		else
			TweenAnim('Firing', 0.5);
	}

	function EndState()
	{
		bFire = 0;
		bAltFire = 0;
		Super.EndState();
	}

ShieldDown:
	Disable('AnimEnd');
	FinishAnim();
	GotoState('Attacking');

Challenge:
	Disable('AnimEnd');
	Acceleration = vect(0,0,0); //stop
	DesiredRotation = Rotator(Enemy.Location - Location);
	PlayChallenge();
	FinishAnim();
	TweenToFighter(0.1);
	Goto('FaceTarget');

ShieldUp:
	Disable('AnimEnd');
	Acceleration = vect(0,0,0); //stop
	FinishAnim();
	TweenAnim('HoldShield', 0.1);
	DesiredRotation = Rotator(Enemy.Location - Location);
	Sleep(duckTime + FRand());
	if (NeedToTurn(Enemy.Location))
		TurnToward(Enemy);
	Goto('CheckDist');

Begin:
	Acceleration = vect(0,0,0); //stop
	DesiredRotation = Rotator(Enemy.Location - Location);
	TweenToFighter(0.15);
	
FaceTarget:
	Disable('AnimEnd');
	if (NeedToTurn(Enemy.Location))
	{
		PlayTurning();
		TurnToward(Enemy);
		TweenToFighter(0.1);
	}
	FinishAnim();

CheckDist:
	if (VSize(Location - Enemy.Location) < 0.9 * MeleeRange + CollisionRadius + Enemy.CollisionRadius)
		GotoState('MeleeAttack', 'ReadyToAttack'); 

ReadyToAttack:
	if (!bHasRangedAttack)
		GotoState('Attacking');
	DesiredRotation = Rotator(Enemy.Location - Location);
	PlayRangedAttack();
	Enable('AnimEnd');
Firing:
	TurnToward(Enemy);
	Goto('Firing');
DoneFiring:
	Disable('AnimEnd');
	KeepAttacking();  
	Goto('FaceTarget');
}

function PlayActWaiting()
{
  PlayAnim('Breath');
}

defaultproperties
{
				WeaponType=Class'UnrealShare.DispersionPistol'
				LungeDamage=20
				SpinDamage=15
				ClawDamage=10
				CarcassType=Class'UnrealI.TrooperCarcass'
				RangedProjectile=None
				GroundSpeed=400.000000
				Health=170
				CombatStyle=0.300000
				Skin=Texture'UnrealI.Skins.sktrooper1'
				Mesh=LodMesh'UnrealI.sktrooper'
				CollisionRadius=32.000000
				CollisionHeight=42.000000
				Mass=125.000000
				Buoyancy=125.000000
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: zo 11-11-2012 21:10:30.000 - Creation time: zo 11-11-2012 21:14:18.100 - Created with UnCodeX