Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

Engine.Teleporter


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
///=============================================================================
// Teleports actors either between different teleporters within a level
// or to matching teleporters on other levels, or to general Internet URLs.
//=============================================================================
class Teleporter extends NavigationPoint
    native;

#exec Texture Import File=Textures\Teleport.pcx Name=S_Teleport Mips=Off Flags=2

//-----------------------------------------------------------------------------
// Teleporter URL can be one of the following forms:
//
// TeleporterName
//		Teleports to a named teleporter in this level.
//		if none, acts only as a teleporter destination
//
// LevelName/TeleporterName
//     Teleports to a different level on this server.
//
// Unreal://Server.domain.com/LevelName/TeleporterName
//     Teleports to a different server on the net.
//
var() string URL;

//-----------------------------------------------------------------------------
// Product the user must have installed in order to enter the teleporter.
var() name ProductRequired;

//-----------------------------------------------------------------------------
// Teleporter destination flags.
var() bool    bChangesVelocity; // Set velocity to TargetVelocity.
var() bool    bChangesYaw;      // Sets yaw to teleporter's Rotation.Yaw
var() bool    bReversesX;       // Reverses X-component of velocity.
var() bool    bReversesY;       // Reverses Y-component of velocity.
var() bool    bReversesZ;       // Reverses Z-component of velocity.

// Teleporter flags
var() bool    bEnabled;         // Teleporter is turned on;

//-----------------------------------------------------------------------------
// Teleporter destination directions.
var() vector  TargetVelocity;   // If bChangesVelocity, set target's velocity to this.

// AI related
var Actor TriggerActor;     //used to tell AI how to trigger me
var Actor TriggerActor2;

//-----------------------------------------------------------------------------
// Teleporter destination functions.

function PostBeginPlay()
{
    if (URL ~= "")
        SetCollision(false, false, false); //destination only
        
    if ( !bEnabled )
        FindTriggerActor();
    Super.PostBeginPlay();
}

function FindTriggerActor()
{
    local Actor A;

    TriggerActor = None;
    TriggerActor2 = None;
    ForEach AllActors(class 'Actor', A)
        if ( A.Event == Tag)
        {
            if ( Counter(A) != None )
                return; //FIXME - handle counters
            if (TriggerActor == None)
                TriggerActor = A;
            else
            {
                TriggerActor2 = A;
                return;
            }
        }
}

// Accept an actor that has teleported in.
function bool Accept( actor Incoming )
{
    local rotator newRot, oldRot;
    local int oldYaw;
    local float mag;
    local vector oldDir;
    local pawn P;

    // Move the actor here.
    Disable('Touch');
    //log("Move Actor here "$tag);
    newRot = Incoming.Rotation;
    if (bChangesYaw)
    {
        oldRot = Incoming.Rotation;
        newRot.Yaw = Rotation.Yaw;
    }

    if ( Pawn(Incoming) != None )
    {
        //tell enemies about teleport
        P = Level.PawnList;
        While ( P != None )
        {
            if (P.Enemy == Incoming)
                P.LastSeenPos = Incoming.Location; 
            P = P.nextPawn;
        }
        Pawn(Incoming).SetLocation(Location);
        Pawn(Incoming).ClientSetRotation(newRot);
        Pawn(Incoming).MoveTimer = -1.0;
        Pawn(Incoming).MoveTarget = self;
    }
    else
    {
        if ( !Incoming.SetLocation(Location) )
            return false;
        if ( bChangesYaw )
            Incoming.SetRotation(newRot);
    }

    Enable('Touch');

    
    if (bChangesVelocity)
        Incoming.Velocity = TargetVelocity;
    else
    {
        if ( bChangesYaw )
        {
            if ( Incoming.Physics == PHYS_Walking )
                OldRot.Pitch = 0;
            oldDir = vector(OldRot);
            mag = Incoming.Velocity Dot oldDir;     
            Incoming.Velocity = Incoming.Velocity - mag * oldDir + mag * vector(Incoming.Rotation);
        } 
        if ( bReversesX )
            Incoming.Velocity.X *= -1.0;
        if ( bReversesY )
            Incoming.Velocity.Y *= -1.0;
        if ( bReversesZ )
            Incoming.Velocity.Z *= -1.0;
    }   

    // Play teleport-in effect.
    PlayTeleportEffect(Incoming, true);
    return true;
}

function PlayTeleportEffect(actor Incoming, bool bOut)
{
    if ( Incoming.IsA('Pawn') )
    {
        Incoming.MakeNoise(1.0);
        Level.Game.PlayTeleportEffect(Incoming, bOut, true);
    }
}

//-----------------------------------------------------------------------------
// Teleporter functions.

function Trigger( actor Other, pawn EventInstigator )
{
    local int i;

    bEnabled = !bEnabled;
    if ( bEnabled ) //teleport any pawns already in my radius
        for (i=0;i<4;i++)
            if ( Touching[i] != None )
                Touch(Touching[i]);
}

// Teleporter was touched by an actor.
function Touch( actor Other )
{
    local Teleporter Dest;
    local int i;
    local Actor A;
    
    if ( !bEnabled )
        return;

    if( Other.bCanTeleport && Other.PreTeleport(Self)==false )
    {
        if( (InStr( URL, "/" ) >= 0) || (InStr( URL, "#" ) >= 0) )
        {
            // Teleport to a level on the net.
            if( PlayerPawn(Other) != None )
                Level.Game.SendPlayer(PlayerPawn(Other), URL);
        }
        else
        {
            // Teleport to a random teleporter in this local level, if more than one pick random.
            foreach AllActors( class 'Teleporter', Dest )
                if( string(Dest.tag)~=URL && Dest!=Self )
                    i++;
            i = rand(i);
            foreach AllActors( class 'Teleporter', Dest )
                if( string(Dest.tag)~=URL && Dest!=Self && i-- == 0 )
                    break;
            if( Dest != None )
            {
                // Teleport the actor into the other teleporter.
                if ( Other.IsA('Pawn') )
                    PlayTeleportEffect( Pawn(Other), false);
                Dest.Accept( Other );
                if( (Event != '') && (Other.IsA('Pawn')) )
                    foreach AllActors( class 'Actor', A, Event )
                        A.Trigger( Other, Other.Instigator );
            }
            else Pawn(Other).ClientMessage( "Teleport destination not found!" );
        }
    }
}

/* SpecialHandling is called by the navigation code when the next path has been found.  
It gives that path an opportunity to modify the result based on any special considerations
*/

function Actor SpecialHandling(Pawn Other)
{
    local int i;
    if ( bEnabled )
    {
        for (i=0;i<4;i++)
            if (Touching[i] == Other)
                Touch(Other); 
        return self;
    }

    if (TriggerActor == None)
    {
        FindTriggerActor();
        if (TriggerActor == None)
            return None;
    }

    if ( (TriggerActor2 != None) 
        && (VSize(TriggerActor2.Location - Other.Location) < VSize(TriggerActor.Location - Other.Location)) )
        return TriggerActor2;
                    
    return TriggerActor;            
}   
    

defaultproperties
{
     bEnabled=True
     bDirectional=True
     Texture=Texture'Engine.S_Teleport'
     SoundVolume=128
     CollisionRadius=18.000000
     CollisionHeight=40.000000
     bCollideActors=True
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: za 22-4-2006 13:00:12.000 - Creation time: za 22-4-2006 13:01:34.203 - Created with UnCodeX